forum galerie-photo
galerie-photo, le Site Français de la Photographie Haute Résolution

 grand-angle et PDC!
Auteur: Edouard F 
Date:   15-03-2005 20:12

Je viens de m'acheter un ss110XL pour ma chambre 20x25. Le but recherché etait le gain en PDC.
Or pour savoir à peu près où etait le gain, j'ai regardé sur une grille la differance de pdc d'un 110 à f/22 par ex par rapport à un 480 à f/22 à même rapport d'agrandissement. Or je ne sais pas trop quoi en conclure... Je ne vois pas de differance !? Ce sont les mêmes valeures.
Ai-je mal lu, ou bien pourquoi dit-on qu'un grand-angle à plus de PDC ?

EFz


 
 Re: grand-angle et PDC!
Auteur: François Laboureix 
Date:   15-03-2005 20:39

Bonjour Edouard.

Il est normal de ne pas trouver de différence car la pdc dépend du rapport d' agrandissement. Si le diaphragme est le même, pour un même rapport de grandissement, la pdc est la même,même pour des focales différentes.
Au prix du 110 XL, la leçon est un peu chère, mais ne regrettez surtout pas votre achat, je crois quec'est une super optique.

François


 
 Re: grand-angle et PDC!
Auteur: François Laboureix 
Date:   15-03-2005 20:56

Pardon Edouard,
j'ai oublié de répondre a votre dernière question. On dit souvent qu' un grand angle donne plus de pdc qu'une longue focale...Ceci est vrai si les deux objectifs sont à la même distance du sujet sur lequel la mise au point a été faite. A ce moment là, le rapport de grandissement offert par le GA est plus petit que celui du télé donc la pdc du GA est plus grande. Si, par contre, vous reculez votre focale plus longue jusqu'à ce qu' elle vous donne un rapport de grandissement identique au GA, la distance de map va augmenter, le rapport va diminuer et vous allez "récupérer" votre pdc qui augmente quand la distance augmente.Pour la demonstration agrémentée de formules magiques, demandez à Emmanuel, il connait ça par coeur.


 
 Re: grand-angle et PDC!
Auteur: Edouard F 
Date:   15-03-2005 21:30

Merci François. :-)

Comment peut on dire que les GA ont plus de PDC!!! C'est fou!
Le prochain qui dit ça je lui fais sa fête! :-)

EFz


 
 Re: grand-angle et PDC!
Auteur: Emmanuel Bigler 
Date:   18-03-2005 07:41

Hmmmm... je me suis donné le temps de la réflexion avant de répondre.
La règle de François L. est belle est bonne tant que l'on est en proxiphoto.
Si on s'approche d'une distance égale à l'hyperfocale du grand angle cela ne marche plus mais la preuve ne tombe pas sous le sens.

Elle vient du fait que pour un CdC donné "c" et pour un nombre d'ouverture donné 'N' l'hyperfocale croît comme le carré de la focale.

H = f*f/(N*c)

(vous m'la copierez pour la peine ;-);-)

Mettez au point sur l'hyperfocale du grand angle, la PdC devient infinie dans le modèle classique ; de H/2 à l'infini.

Pour que la longue focale, de focale en gros 4 fois plus longue, travaille au même grandissement, il faut se mettre 4 fois plus loin. à cette distance on est encore loin de l'hyperfocale de l'optique longue focale qui est 4x4 = seize fois plus grande. Donc le grand angle atteint une PdC infine pour un grandissement où la longue focale a une PdC peut-être grande mais finie.

La règle de la seule dépendance de la PdC vis à vis du nombre d'ouverture et du grandissement est vraie en toute rigueur au rapport 1:1 sans discussion, elle reste vraie approximativement en proxiphoto (je reste flou sur le domaine devalidité, faites une simulation;-) elle tombe en défaut au voisinage de l'hyperfocale du grand angulaire.

Donc vous avez raison tous les deux mais à condition de ne pas se mettre trop loin.
En paysage en ragardant au loin, le grand angle a plus de profondeur de champ même en travailant au même grandissement, même N et même critère de netteté.
C'est subtil j'en conviens.

Une 'tite simulation avec le bon Calcphot de Simon Clément à télécharger sur galerie-photo vous expliquera tout.
Et en plus les formules de Simon C. sont bonnes même pour les terribles rétrofocus dissymétrques !!


 
 Re: grand-angle et PDC! voici la simulation !
Auteur: Emmanuel Bigler 
Date:   18-03-2005 10:49

J'ai fait une simulation de profondeur de champ par tracé des fonctions classiques, en utilisant gnuplot, traceur libre et gratuit pour toute plateforme.

Dans le cas particulier les optiques de 110 et de 480, jusqu'à un grandissement de l'ordre de 1:10 à 1:20 les profondeurs de champ totales sont quasi-identiques si on travaillle au même grandissement et au même nombre d'ouverture, mais au-delà de 1:50, le grand angle l'emporte en PdC parce qu'on se rapproche de l'hyperfocale (calcul fait à f/22)

Voici le code source du fichier gnuplot à charger pour tracer la démo.
Les dièses # sont des comentaires dans le code source pour expliquer ce qu'on fait. Mes commentaires s'appliquent à la ligne de commande qui suit le commentaire.
Veuillez conserver ces dièses SVP merci.
Ne pas couper / replier les lignes dans votre navigateur les lignes longues doivent aller jusqu'au bout sans être repliées. Coupez-collez en ASCII vers votre presse-papiers favori.

#---------------------couper ici et sauvegarder en pur texte sous un nom quelconque genre pdc.plt---------------------------
#
# gnuplot est un logiciel de tracé de courbes & surfaces libre & gratuit
# pour tout système d'exploitation à télécharger ici
# ftp://ftp.irisa.fr/pub/mirrors/gnuplot
# http://www.gnuplot.info
#
# remet toutes les options à leur valeur standard
reset
#
# pour les caractères accentués dans les titres
set encoding iso_8859_1
# définit un intervalle de départ suivant x ; ici on trace en fonction de l'inverse
# du grandissement entre 1 et 15
set xrange [ 1.00 : 20.0 ]
#
#
# définition ds fonctions
# hyperfocale en millimètres, focale en millimètres,
# c en millimères, n nombre d'ouverture sans dimension
h(f,c,n)=f*f/(n*c)
#
# distance "p" entre l'objet et le plan principal image
# en fonction de l'invers du grandissement un_sur_g
p(f,un_sur_g)=f*(1.+un_sur_g)
#
# distances proche "p1" et lointaine "m2" de netteté acceptable ;
# formule valables pour optiques quasi symétrique uniquement
# en millimètres
p1(p,f,c,n)=1/(1/p+(1/h(f,c,n))*(1-f/p))
p2(p,f,c,n)=1/(1/p-(1/h(f,c,n))*(1-f/p))
#
#
# profondeur de champ totale en millimètres
pdc(p,f,c,n)=p2(p,f,c,n)-p1(p,f,c,n)
#
# idem mais on ne la trace que pour des valeurs raisonnables, par trop grande et positives
# on fait un test et pour ne rien tracer on demande à gnuplot de tracer un truc impossible
# par exemple de tracer la valeur 1/0 ; dans ce cas gnuplot ne trace pas
# ci-dessous il y deux test imbriqué c'est un peeu dur à lire
# syntaxe : (montruc satisfait telle condition ? tracer montruc : sinon ne rien tracer du tout)
#
pdc2(p,f,c,n)=(abs(pdc(p,f,c,n))<100000? ( pdc(p,f,c,n)>=0?pdc(p,f,c,n):1/0 ) :1/0)
#
# idem mais valeur de sortie exprimée en mètres
# lorsque la distance p_m est exprimée en mètres.
pdc2_m(p_m,f,c,n)=(.001*(abs(pdc(p_m*1000.,f,c,n))<100000? ( pdc(p_m*1000.,f,c,n)>=0?pdc(p_m*1000.,f,c,n):1/0 ) :1/0))
#
#idem mais valeur de sortie en mètres en fonction du grandissement sans dimension
# f,c son en millimètres.
pdc2_gm(un_sur_g,f,c,n)=.001*(abs(pdc(p(f,un_sur_g),f,c,n))<100000? ( pdc(p(f,un_sur_g) ,f,c,n)>=0?pdc(p(f,un_sur_g),f,c,n):1/0 ) :1/0)
#
#
#
# définition des valeurs courantes pour démarrer,
# après tracé on réaffecte de nouvelle valeurs à volonté et on fait 'replot'
# un dixième pour c c'est laxiste en 9x12 mais très strict en 20x25
#
c = 0.1
#
# diaph de travail le même dans les deux cas
# nombre d'ouverture sans dimension
n = 22
#
# définition des focales en millimètres
f1=110.
f2=480.
#
#
# affichage des fonctions et des valeurs des variables en cours
sho func
sho var
# affichage des hyperfocales classiques
pr "Hyperfocale(f1=",f1,"mm)=", int(.1*h(f1,c,n)+.5)*.01, " m ; Hyperfocale(f2=",f2,"mm)=", int(.1*h(f2,c,n)+.5)*.01," m"
#
#
# Enfin, tracé des deux courbes donannt la profondeur de champ totale en mètres
# en fonction du grandissement pour les deux focales f1 et f2.
#
# Titres et textes sur les axes
set title "Comparaison de profondeur de champ pour deux focales différentes f1 et f2\nlorsque le nombre d'ouverture et le grandissement sont les mêmes"
set xlabel "Inverse du grandissement : soit objet/image"
set ylabel "Profondeur de champ totale (p2 - p1) exprimée en mètres"
#
# Enfin on trace
plot pdc2_gm(x,f1,c,n),pdc2_gm(x,f2,c,n)
#----------FIN DE FICHIER-----------------------


 
 Re: grand-angle et PDC!
Auteur: Edouard Fz 
Date:   20-03-2005 22:15

D'accord d'accord... :-)
intéresse pour fignoler le problème.
Mais vu que je travaille uniquement en proxiphoto...

*Je me suis effectivement payé des 480 Api Ronar à Chelles... et j'en suis bien content.
Reste plus qu'à me trouver une optique standard au top (meilleur que mes 2 symmar 300 et 240 !)

Merci à vous.
EFz


 
 Re: grand-angle et PDC!
Auteur: Emmanuel Bigler 
Date:   20-03-2005 22:58

Un petit croquis vaut mieux qu'on long discours. J'ai mis ci-dessous la courbe de comparaison des PdC totales entre un 110 et un 480 pour c=0,1 mm et N=22 en fonction du grandissement, suivant la simulation gnuplot ci-dessus. (lien valable 14 jours à compter du 20/03/05)
http://cjoint.com/?duxjxg5ppw


 
 Re: grand-angle et PDC!
Auteur: Philippe Do 
Date:   20-03-2005 23:04

Merci Emmanuel!


 
 Re: grand-angle et PDC!
Auteur: François Laboureix 
Date:   20-03-2005 23:06

Mes plus sincères excuses à Edouard pour lui avoir causé de grosses frayeurs et à Emmanuel pour avoir piétinné les règles de l'optique en faisant une généralité d' un cas particulier...Je dois avouer que mon dernier achat m'a sans doute aveuglé: c'était un macro Schneider HM...
Je garde un bouteille de champagne au frais pour oublier tout ça, mais je ne livre pas...


 
 Re: grand-angle et PDC!
Auteur: Edouard Fz 
Date:   20-03-2005 23:21

Merci Emmanuel. :-)
François, ce sont de vrais grosses frayeurs que vous m'avez causés! :-)
Je bosse en proxiphoto et à voir le croquis... les courbes se superposent énormément jusqu'à 15m...

EFz


 
 Re: grand-angle et PDC!
Auteur: Emmanuel Bigler 
Date:   20-03-2005 23:22

François L.

La pratique du grand format n'est-elle pas au départ un pied de nez aux braves gens qui n'aiment pas que l'on suive une autre route photographique qu'eux? alors piétinons joyeusement, expérimentons, trompons nous, peu importe. Ce forum est le lieu où on peut poser toutes les con,jectures techniques photographiques qu'on veut, de la libre confrontation sort toujoursune amélioration de nos connaissances.
Et puis il y a peut-être une erreur dans mon fichier de commandes ;-)

Il y a deux domaines de l'optique photographique traditionnelle où la prudence la plus extrême s'impose avant de parier sur un résultat même avec un ami de longue date ;-)
- les questions de comparaison de profondeur de champ entre focales et formats,
- les questions de photométrie.
Ce sont les trucs le plus casse-g.... qui soient si on ne s'est pas bien mis d'accord sur la procédure, la mesure, le but recherché, etc...
Qui aurait pu croire, par exemple, qu'un ciel gris d'hiver, mesuré bas sur l'horizon,est plus gris que la neige qu'il est pourtant censé illuminer !!!

Donc vous boirez à la santé des échanges sur galerie-photo !


 
 Re: grand-angle et PDC!
Auteur: François Laboureix 
Date:   21-03-2005 10:13

Emmanuel,

merci de votre indulgence. Rassurez vous, je continuerai à piétiner d' impatience, souvent, mais aussi les plate-bandes trop bien alignées...
Au fait, faut-il couper les fils télégraphiques qui, après l'averse,nous proposent un reflet blanc d'une incongruité insupportable ?
François L.




 
Retour à l'index général
le forum de galerie photo : http://www.galerie-photo.info/forum
galerie-photo, le Site Français de la Photographie Haute Résolution